Silent install script

From WikiPaul - Paul Swanson's wiki

Put the following into a text file, then rename it to _Install all programs.bat, making sure to replace the .txt with .bat

@echo off
:: This script determines operating system version and bit, then 
:: installs software packages silently
:: In Vista with UAC on, right-click it and select Run As Administrator. 
:: With UAC off, and in Windows XP, just double click the file.

echo Script Version 2008-11-25
echo Last change: Updated Firefox profile
 
Set RegQry=HKLM\Hardware\Description\System\CentralProcessor\0
 
REG.exe Query %RegQry% > temp.txt
 
Find /i "x86" < temp.txt > StringCheck.txt
 
If %ERRORLEVEL% == 0 (
    set bit=32
) ELSE (
    set bit=64
)

:: Vista is Windows 6.0
ver > temp.txt
Find /i "Version 6.0" < temp.txt > StringCheck.txt

if %ERRORLEVEL% == 0 (
    set win=V
) ELSE (
    set win=X
)

:: The following line sets the script path to the directory the
:: bat file is in. When Run as Administrator in Vista, cmd.exe
:: automatically changes the path, so this puts it back.
cd /d %~dp0

:: If you set up a Firefox profile like you want, you can 
:: pull the Mozilla folder out of Application Data, and
:: this will copy it over
echo Installing Firefox 3.0.4
mozilla_firefox-3.0.4.exe -ms

echo Copying Firefox profile
xcopy /EIC "Mozilla" "%APPDATA%/Mozilla" 

echo Installing VLC 0.9.6
vlc-0.9.6-win32.exe /S

if %bit% == 32 (
    echo Installing 7-zip 32
    7zip-4.57.exe /S
) ELSE (
    echo Installing 7-zip 64
    7z457-x64.msi /quiet
)

echo Installing Infrarecorder 0.461
infrarecorder-0.461.exe /S

echo Installing Flash 10
flash-10.0.12.36.exe /s

ECHO Installing Adobe Reader 9
adobe_reader-9.0.exe /sAll /rs

echo Installing Java 6.10
jre-6u10-windows-i586-p-s.exe /s /v "/qn IEXPLORER=1 MOZILLA=1 ADDLOCAL=ALL JAVAUPDATE=0 WEBSTARTICON=0"

if %win% == X (
    echo Installing IE7
    IE7-WindowsXP-x86-enu.exe /quiet /update-no /no-default /norestart
)

"_Install AVG only.bat"

_Install AVG only.bat

@echo off

echo Installing AVG 8.0
avg_free_stf_en_8_173a1373.exe /hide /no_welcome /REMOVE_FEATURE fea_AVG_SafeSurf /REMOVE_FEATURE fea_AVG_SafeSearch

pause